用ASP+XML打造留言本   

［ 作者：佚名    转贴自：本站原创    点击数：1    更新时间：2004-1-16    文章录入：7788zpt ］ 

一、读者指引

　　读者指引帮助你掌握本文的梗概。以免你看了大半才明白这编文章不适合你，给你造成视觉污染。

　　如果你正在用ASP+XML写一些程序，或者你正在学XML那就值得一看。

　　阅读本文须具备的知识，对ASP有基本的了解，对XML和DOM有基本了解，如果你不了解那么你通过学习本文基本上能够
撑握ASP＋XML和DOM的应用，并能根据本文范写出自已更高级的ASP＋XML程序。

　　二、基本思想

　　本文思想是基于用ASP和DOM来读取和存储XML数据，并利用XML数据来存储留言信息，达到同用数据库存储数据的功
能。

　　三、XML留言本的优势

　　或许你会问用ASP＋TXT文本也可以达到不用数据库实上留言的功能，不错确实能够做到，而且网上也有很多这样的留
言本免费下载，但这里我要讲一下ASP＋XML的优越性。

　　１、XML＋ASP比ASP＋TXT速度要快。可能你也发现当TXT文件很少时速度出奇的快，但是随着留言信息的增加TXT文本
变大，速度却又是出奇的慢这就是ＡＳＰ＋TXT的弱点。当然我不能说ＡＳＰ＋XML就一定是出奇的快，但是比起ＡＳ
Ｐ＋TXT来说是快了许多，当然随着留言信息的增加ＸＭＬ文本增大速度也下降很快，但是比起TXT来说就还是好了许多
（这一点可以从ＷＡＳ测试证明读者可以自行测试），当然ＡＳＰ＋XML比不上数据库，因为数据库对查询做了特别的优
化，而XML只是纯文本，在ＡＳＰ建立对像是要把ＸＭＬ数据全部读入内存中，如果数据量大的话可想而知速度会慢下来。
那你也许会问那我什么时候用关系数据库存储数据，又什么时候用XML存储数据呢？我这里也顺便提一下，就是当数据比较
复杂无规率时用XML数据比较合适，还有就是你打算这些数据要在不同的操作系统上读取运用时那就是XML大显身手的时候
了。如果你是普通的数据那么不到关键时刻或不支持数据库的空间时还是不要用XML文件来存储数据为好。
　　２、XML数据的易读取性，TXT文本是比较难操作的，我们必须一行一行的读取判断，而且很多功能无法实上，只能编
制比较简单的留言本，而ＸＭＬ数据则不同了，利用DOM可以轻易的访问每一个节点，而不是TXT那些烦人的Readline()
Witeline()了，我们可以随意的加入删除更新某一个我们感兴趣的节点，利用ASP或者ＪＳ或者数据岛都可以轻松实上这一
点，当然我这里为发考虑兼容性，用了ASP来读取XML数据，而没有用数据岛来读取节点数据（因为只有ＩＥ５以上版本才
支持数据岛技术）而用ASP来实上就不存在这些问了因为客户得到的是HTML文件。

　 ３、XML数据夸操作系统性，只要我们把这些数据存储为XML那么这些数据就能被应何基它语言或系统所识别，而不用做
应何改动。TXT显然不具备这些性能。例如我们在网上的留言信息可以直接被被转换成wap格式在手机上显示。

　　四、建立存储留言信息的XML文件(List.xml)　　我们这里不打算使用ＤＴＤ，因为我们这是我们自已编制并测试通过的XML数据，所以不需要ＤＴＤ来验证（如果你对
此感兴趣当然可以加一个这不影响程序的运行）。现在我们来看看建立一个留言本的基本要素

　　０、留言ＩＤ号--定义为＜id＞

　　１、用户名我们--定义为＜username＞

　　２、来自那里们--定义为＜fromwhere＞

　　３、留言时间定--义为＜Posttime＞

　　４、用户主页定--义为＜homepage＞

　　５、用户的信箱--定义为＜email＞

　　６、留言内容定--义为＜text＞

　　当然以上不是必须的读者可以自行命名并加减相关标签，把它们组合起来就得到List.xml的文件了

＜?xml version="1.0" encoding="gb2312"?＞
＜site＞
　　　＜NewList＞
　　　　　　＜list＞
　　　　　　　　＜id＞1＜/id＞
　　　　　　　　＜username＞苛子＜/username＞
　　　　　　　　＜fromwhere＞中国广州＜/fromwhere＞
　　　　　　　　＜Posttime＞01-4-23 18:26:56＜/Posttime＞
　　　　　　　　＜homepage＞http://page2000.xiloo.com＜/homepage＞
　　　　　　　　＜email＞lucaihui@cmmail.com＜/email＞
　　　　　　　　＜text＞这是我的第一个XML文件＜/text＞
　　　　　　＜/list＞
　　　＜/NewList＞
＜/site＞

　　注意：必须加上encoding="gb2312"否则会报错为非法字符，因为XML默认不支持中文。＜site＞为根节点＜NewList＞
＜ist＞等为子节点。对这个文件的意思我就不多说了大家也应该看的明白了。接下来就是我们如何来显示它了。

五、建立显示XML数据的ASP文件(index.asp)

　　这个文件要实现的功能就是读取并显示XML数据，首先创建一个XML对像然后把XML读入内存中，利用DOM分离出我们所
要的数据。

＜%
strSourceFile = Server.MapPath("/") & "\List.xml"
'获取XML文件的路径这里根据你的虚拟目录不同而不同
Set objXML = Server.CreateObject("Microsoft.FreeThreadedXMLDOM")
'以自由线程创建一个XML对像
objXML.load(strSourceFile)'把XML文件读入内存
Set objRootsite = objXML.documentElement.selectSingleNode("NewList")
'选取NewList节点
%＞
＜html＞
＜head＞
＜title＞留言本＜/title＞
＜meta http-equiv="Content-Type" content="text/html; charset=gb2312"＞
＜style type="text/css"＞
＜!--
td { font-family: "宋体"; font-size: 9pt; text-decoration: none}
a { font-family: "宋体"; font-size: 9pt; color: #0066CC; text-decoration: none}
a:hover { color: #FF6600; text-decoration: underline}
--＞
＜/style＞
＜/head＞＜body bgcolor="#0099CC" text="#000000"＞
＜table width="80%" border="0" cellspacing="1" cellpadding="4" align="center" bgcolor="#CCCCCC"＞
＜tr bgcolor="#000000"＞
＜td colspan="2"＞＜font color="#FFFFFF"＞留言溥 ＜a href="PostNew.asp"＞＜font color=#FFFFFF＞写新留言
＜/font＞＜/a＞＜/font＞＜/td＞
＜/tr＞
＜%
PageSize =10'假设每页显示10条留言
AllNodesNum =objRootsite.childNodes.length-1
'获取子节点数据（因为是从节点数从0开始的所最大子节点数要减1）
PageNum=AllNodesNum\PageSize+1'算出总页数
PageNo=request.querystring("PageNo")
if PageNo="" then'如果是每一次获得页面则定位到每一页显示最新的留言
PageNo=PageNum
end if
StarNodes=PageNo*PageSize-1'获得起始节点
EndNodes=(PageNo-1)*PageSize'获得结束节点
if EndNodes＜0 then
EndNodes=0
end if
if StarNodes＞AllNodesNum then'判断起始节点数是否超过总的节点数
EndNodes=EndNodes-(StarNodes-AllNodesNum)
'如果超过则结束节点要减去(StarNodes-AllNodesNum)的差值否则下标会超界出错
StarNodes=AllNodesNum
end if
if EndNodes＜0 then
EndNodes=0
end if
while StarNodes＞=EndNodes
'从结束节点到超始节点之间读取节点数据
username = objRootsite.childNodes.item(StarNodes).childNodes.item(1).text
'获得用户名
fromwhere = objRootsite.childNodes.item(StarNodes).childNodes.item(2).text
'获得用户来自那里
Posttime = objRootsite.childNodes.item(StarNodes).childNodes.item(3).text
'获得留言时间
homepage = objRootsite.childNodes.item(StarNodes).childNodes.item(4).text
'获得用户主页
email = objRootsite.childNodes.item(StarNodes).childNodes.item(5).text
'获得用户Eamil
text = objRootsite.childNodes.item(StarNodes).childNodes.item(6).text
'获昨留言内容

'*****************************************************************************
'这里使作了XML的DOM来读取数据,显然objRootsite对像所对应的节点为＜NewList＞
' objRootsite.childNodes.item(StarNodes)所对应的节点就是＜list＞节点因为不至一个＜list＞节点所以用了item()
来识别当前节点数据，随着StarNodes的递减＜list＞节点根着往上移一个个读取＜list＞节点数据。
'objRootsite.childNodes.item(StarNodes).childNodes.item(1).text所对应的节点为具体的每个节点的文本值，这里
(1)所对应的就是username用户名（因为＜list＞节点的子节点才是我们真正所要的）
'******************************************************************************

text = replace(text,chr(13),"＜br＞")
'替代回车
text = replace(text,chr(32)," ")
'替代空格
%＞
＜tr bgcolor="#F0F0F0"＞
＜td width="21%" height="94" valign="top"＞姓 名：＜%=username%＞＜br＞
来 自：＜%=fromwhere%＞＜br＞
＜/td＞
＜td width="79%" height="94" valign="top"＞ | ＜a href="＜%=homepage%＞" target=_blank title="＜%=username%
＞的主页"＞主页＜/a＞
| | ＜a href="mailto:＜%=email%＞" title="给＜%=username%＞写信"＞信箱＜/a＞ | |＜font color="#CC6633"＞
留言时间：＜%=Posttime%＞ ＜/font＞|
＜hr＞
＜%=text%＞ ＜/td＞
＜/tr＞
＜tr bgcolor="#FFFFFF" align="right"＞
＜td colspan="2"＞ ＜/td＞
＜/tr＞
＜%
StarNodes=StarNodes-1
wend
set objXML=nothing
%＞
＜tr bgcolor="#FFFFFF" align="right"＞
＜td colspan="2"＞ 共有<＜%=PageNum%＞>页
＜%
if cint(PageNo)＜＞PageNum then'分页
response.write "＜a href='index.asp?PageNo="&(PageNo+1)&"'＞上一页＜/a＞"
end if
if cint(PageNo)＜＞1 then
response.write "＜a href='index.asp?PageNo="&(PageNo-1)&"'＞下一页＜/a＞ "
end if
%＞
＜/td＞
＜/tr＞
＜/table＞
＜/body＞
＜/html＞

六、建立写新留言程序(PostNew.asp)

　　这个文件要实现的功能就是写入新的XML节点，首先创建一个XML对像然后把XML读入内存中，利用appendChild()方法
加入我们生成的XML节点。

＜%
username=request.form("username")
if username＜＞"" then
fromwhere =request.form("fromwhere")
homepage =request.form("homepage")
email =request.form("email")
text =request.form("text")
text =replace(text,"＜","<")
Posttime =now()
strSourceFile = Server.MapPath("/") & "\List.xml"
'获取XML文件的路径这里根据你的虚拟目录不同而不同
Set objXML = Server.CreateObject("Microsoft.XMLDOM")
'创建XML对像
objXML.load(strSourceFile)
'把XML文件读入内存中
Set objRootlist = objXML.documentElement.selectSingleNode("NewList")
'选取＜NewList＞节点
if objRootlist.hasChildNodes then
'判断＜NewList＞是否有子节点（因为如果是每一次＜NewList＞是没有子节点的，
’ 如果不加判断在第一次运得时就会报错
id = objRootlist.lastchild.firstchild.text+1
'这里获得将要插入子节点的ＩＤ号，其ＩＤ号为＜NewList＞的最后一个子节点(lastchild)的第一个子节点(firstchild)
的ＩＤ号加1（这里我们按照关系型数据库的ＩＤ号来递增）
else
'如是没有字子节点则是第一次留言ＩＤ号设为１
id=1
end if
brstr=chr(13)&chr(10)&chr(9)
'为了插入XML文件中的节点换行空格排列整齐
’（当然你也可以不用这样只是为了XML数据好看而以）
XMLnode=brstr&"＜list＞"&brstr & _
"＜id＞"&id&"＜/id＞"&brstr & _
"＜username＞"&username&"＜/username＞"&brstr & _
"＜fromwhere＞"&fromwhere&"＜/fromwhere＞"&brstr & _
"＜Posttime＞"&Posttime&"＜/Posttime＞"&brstr & _
"＜homepage＞"&homepage&"＜/homepage＞"&brstr & _
"＜email＞"&email&"＜/email＞"&brstr & _
"＜text＞"&text&"＜/text＞"&brstr & _
"＜/list＞"&chr(13)
'根据得到的数据建立XML片段
set objXML2=Server.CreateObject("Microsoft.XMLDOM")
'建立一个新XML对像
objXML2.loadXML(XMLnode)
'把XML版片段读入内存中
set rootNewNode=objXML2.documentElement
'获得objXML2的根节点
objRootlist.appendChild(rootNewNode)
'把XML片段插入到List.xml中
objXML.save(strSourceFile)
'存储lsit.xml文件（因为不存储List.xml只在内存中更新了）
set objXML=nothing
set objXML2=nothing
response.write "谢谢您的留言"
response.end

end if
%＞
＜html＞
＜head＞
＜title＞Untitled Document＜/title＞
＜meta http-equiv="Content-Type" content="text/html; charset=gb2312"＞
＜style type="text/css"＞
＜!--
td { font-size: 9pt}
--＞
＜/style＞
＜/head＞
＜body bgcolor="#0099CC" text="#000000"＞
＜table width="80%" border="0" cellspacing="1" cellpadding="4" align="center" bgcolor="#FFFFFF"＞
＜form action="PostNew.asp" method="post" name="form1"＞
＜tr bgcolor="#000000"＞
＜td colspan="2"＞＜font color="#FFFFFF"＞新留言＜/font＞＜/td＞
＜/tr＞
＜tr bgcolor="#EFEFEF"＞
＜td width="19%" align="right"＞姓 名：＜/td＞
＜td width="81%"＞
＜input type="text" name="username"＞
** ＜/td＞
＜/tr＞
＜tr bgcolor="#EFEFEF"＞
＜td width="19%" align="right"＞来 自：＜/td＞
＜td width="81%"＞
＜input type="text" name="fromwhere" value="中国"＞
＜/td＞
＜/tr＞
＜tr bgcolor="#EFEFEF"＞
＜td width="19%" align="right"＞主 页：＜/td＞
＜td width="81%"＞
＜input type="text" name="homepage" value="http://"＞
＜/td＞
＜/tr＞
＜tr bgcolor="#EFEFEF"＞
＜td width="19%" align="right"＞Email：＜/td＞
＜td width="81%"＞
＜input type="text" name="email"＞
＜/td＞
＜/tr＞
＜tr bgcolor="#EFEFEF"＞
＜td width="19%" align="right" valign="top"＞内 容：＜/td＞
＜td width="81%"＞
＜textarea name="text" cols="60" rows="10"＞＜/textarea＞
＜/td＞
＜/tr＞
＜tr bgcolor="#EFEFEF"＞
＜td width="19%" align="right"＞ ＜/td＞
＜td width="81%"＞
＜input type="submit" name="Submit" value="提交"＞
＜input type="reset" name="Submit2" value="重填"＞
＜/td＞
＜/tr＞
＜/form＞
＜/table＞
＜/body＞
＜/html＞

七、总结

　　到这里我们就建立一个简单并有分页功能的XML留言本了，呵看完了简单吧，其实我这里只起一个抛砖引玉的功能，其目的是引导大家建立更复杂更好的ASP＋XML程序，例如：所上面的留言本加上回复功能，管理功能，点击计数据功能等，甚至你可以把它变一个ＢＢＳ等等。最后留言本运行结果如下：

(List.xml在ＩＥ５下面的运行结果)

<img src="http://www.yesky.com/20010604/jt-2001-6-4-xml.gif">

(留言本index.asp运行结果)

<img src="http://www.yesky.com/20010604/jt-2001-6-4-index.gif">

(PostNew.asp运得结果)

<img src="http://www.yesky.com/20010604/jt-2001-6-4-post.gif">

最后如果你拷贝我上面的程序的不能运行，可是是拷贝时或者是我注释时出错了（不过首页要检查 strSourceFile = Server.MapPath("/") & "\List.xml"这里是否出错了，不过我可以告诉你如果是提示缺少对像那么多是这里出错了），最后你可以到http://Page2000.xiloo.com去下载源程序，也可以给我来信asp_boys@cmmail.com我会尽快给你寄去源程序。如果你有什么问题可以到http://www.4u2v.com/bbs因为我多在那里回答一些我知道的问题。

错误多多。。

XML（Extensible Markup Language）是一种基于文本格式的标记语言，它注重对数据结构和数据意义的描述，实现了数据内容和显示样式的分离，而且是与平台无关的。由于XML注重数据内容的描述，因而，对于数据的检索非常有意义，我们不会再象HTML那样，检索出与我们要求无关的信息。另一方面，XML文件是数据的载体，利用XML作为数据库，不需要访问任何数据库系统，我们可以使用任意WEB技术来显示我们的数据，比如HTML，Flash 5 等。由于世界各大计算机公司的积极参与，XML正日益成为基于互联网的数据格式新一代的标准。下面利用XML作为数据的载体，开发一个基于XML的留言板。

　　首先，我们建立XML文件guestbook.xml，该文件记录了留言者的姓名、电子邮件、网址、留言内容。当然，我们也可以根据需要添加任意多的信息。文件内容如下：

<?xml version="1.0" encoding="gb2312"?>
<留言本>
<留言记录>
　<留言者姓名>孟宪会</留言者姓名>
　<电子邮件>amxh@testDomain.com</电子邮件>
　<网址>http://go.163.com/~colorweb</网址>
　<留言内容>测试成功！！</留言内容>
</留言记录>
</留言本>

　　由于目前许多服务器都支持ASP，我们采用常见的ASP来作为实现的工具，guestbook.asp文件如下：

<%@Language="VBScript"%>
<%
'设置Web页面的信息
Response.Buffer = true
Response.Expires = -1

'显示留言函数init()
Function init()
entryForm()

'定义局部变量
Dim objXML
Dim arrNames
Dim arrEmails
Dim arrURLS
Dim arrMessages

'创建XMLDOM文档对象，用来存放留言
Set objXML = server.createObject("Msxml2.DOMDocument")
objXML.async = false
objXML.load(server.MapPath("guestbook.xml"))

'取得留言本各元素的集合
Set arrNames = objXML.getElementsByTagName("留言者姓名")
Set arrEmails = objXML.getElementsByTagName("电子邮件")
Set arrURLS = objXML.getElementsByTagName("网址")
Set arrMessages = objXML.getElementsByTagName("留言内容")

Response.Write "<table border='0' width='100%'>"
Response.Write "<tr><td bgcolor='#00CCFF' align='center' height='26'>"
Response.Write "<b>各位的留言如下：</b>"
Response.Write "</td></tr>"

'输出留言本各元素的内容，最新的留言先显示
For x=arrNames.length-1 To 0 Step -1
　Response.Write "<tr><td><a href=mailto:" & arrEmails.item(x).text & ">" & arrNames.item(x).text & "</a></td></tr>"
　Response.Write "<tr><td>网址：<a href=" & arrURLS.item(x).text & " target='_blank'>" & arrURLS.item(x).text & "</a><td></tr>"
　Response.Write "<tr><td>留言内容：</td></tr>"
　Response.Write "<tr><td bgcolor='#0099ff'>" & arrMessages.item(x).text &"</td></tr>"
　Response.Write "<tr><td>&nbsp;</td></tr>"
Next

Response.Write "</table>"
Set objXML = nothing
End Function

'向XML文件添加留言记录的函数addEntry()
Function addEntry()

'定义局部变量
Dim strName
Dim strEmail
Dim strURL
Dim strMessage

'取得留言表单的输入内容
strName = Request.Form("姓名")
strEmail = Request.Form("电子邮件")
strURL = Request.Form("网址")
strMessage = Request.Form("留言")

Dim objXML
Dim objEntry
Dim objName
Dim objEmail
Dim objURL
Dim objMessage

'向XML文件添加留言内容
Set objXML = server.createObject("Msxml2.DOMDocument")
objXML.async = false
objXML.load(server.MapPath("guestbook.xml"))

Set objEntry = objXML.createNode("element", "留言记录", "")
objXML.documentElement.appendChild(objEntry)

Set objName = objXML.createNode("element", "留言者姓名", "")
objEntry.appendChild(objName)
objName.text = strName
　
Set objEmail = objXML.createNode("element", "电子邮件", "")
objEntry.appendChild(objEmail)
objEmail.text = strEmail
　
Set objURL = objXML.createNode("element", "网址", "")
objEntry.appendChild(objURL)
objURL.text = strURL
　
Set objMessage = objXML.createNode("element", "留言内容", "")
objEntry.appendChild(objMessage)
objMessage.text = strMessage

objXML.save(server.MapPath("guestbook.xml"))

Response.Redirect("guestbook.asp")

End function

'填写和发送留言表单的函数entryForm()
Function entryForm()

　Response.Write "<p align='center'><b>XML 留言本 例子</b></p>"
　Response.Write "<hr color='#000099' width='100%' noshade>"
　Response.Write "<form action=guestbook.asp?action=addEntry method=post>"
　Response.Write "<table border=1>"
　Response.Write "<tr><td>您的姓名：</td><td><input type=text name=姓名 /></td></tr>"
　Response.Write "<tr><td>电子邮件：</td><td><input type=text name=电子邮件 /></td></tr>"
　Response.Write "<tr><td>您的网址：</td><td><input type=text name=网址 /></td></tr>"
　Response.Write "<tr><td>您的留言：</td><td><textarea name=留言 cols=40 rows=5></textarea></td></tr>"
　Response.Write "<tr><td>&nbsp;</td><td><input type=submit value=发布留言 /></td></tr>"
　Response.Write "</table>"
　Response.Write "</form>"

End Function
%>
<html>
<head>
<title>XML 留言例子</title>
<meta http-equiv="Content-Type" content="text/html; charset=gb2312">
</head>
<body>
<%
'判断是否发送了留言，并更新留言信息
Dim a
a = Request.Querystring("action")
If a<>"" Then
addEntry
else
init
End If
%>
</body>
</html>